arduino uno에서 ds18b20온도 센서값과 RTC(날짜,시간)값을 MYSQL에 데이터 넣기

이번엔 arduino uno를 가지고 좀 복잡한 미니 프로젝트를 했습니다. 

ds18b20 온도 센서로부터 값을 읽어오고 동시에 RTC에 저장된 날짜와 시간 데이터도 읽어옵니다. 

그리고 나서 두 값을 ESP8266 모듈을 이용하여 MYSQL 서버에 접속하여  값들을 저장합니다. 

그리고 마지막으로 웹상에서 그래프를 그려볼것입니다..

mysql에 데이터베이스 및 테이블을 새로 생성합니다. 

$ mysql -u root -p
Enter password: 
Welcome to the MySQL monitor.  Commands end with ; or \g.
Your MySQL connection id is 1576
Server version: 5.5.49-0ubuntu0.14.04.1 (Ubuntu)
 
Copyright (c) 2000, 2016, Oracle and/or its affiliates. All rights reserved.
 
Oracle is a registered trademark of Oracle Corporation and/or its
affiliates. Other names may be trademarks of their respective
owners.
 
Type 'help;' or '\h' for help. Type '\c' to clear the current input statement.
 
mysql> create database testdb;
Query OK, 1 row affected (0.00 sec)
 
mysql> use testdb;
Database changed
mysql> create table data(
    -> date date,
    -> time time,
    -> temperature double
    -> );
Query OK, 0 rows affected (0.02 sec)
 
mysql> exit
Bye
 

/var/www/html 위치에 run.php 파일을 작성합니다. 아래 패스워드입력 부분은 바꾸어 주셔야합니다.

 <?php
 $result = mysql_connect("127.0.0.1", "root", "패스워드");
 $temperature = $_GET["temp"];
 $date = $_GET["date"];
 $time = $_GET["time"];
 $sqlt = "insert into testdb.data values ($date,$time,$temperature)";
 echo "$sqlt";
 $ret = mysql_query($sqlt);
 
?>
 

이제 웹브라우저의 주소 창에 아래 주소를 입력해보면 데이터가 테이블에 입력되는 것을 확인 할 수 있습니다.

http://localhost/run.php?temp=26.2&date="2016-06-10"&time="00:52:00"

이번엔 아두이노 코드로 같은 일을 해보았습니다...

센서 및 RTC, ESP8266과 아두이노 연결은 아래 글들을 참고하세요.. 설치 필요한 라이브러리도 나와있습니다.

틀린점은 본 포스팅에서는 DS18B20의 데이터핀이 5번에 연결된다는 점입니다. 

또하나 틀린점은 ESP8266을 위한 소프트시리얼로 6번 7번핀이 사용된다는 점입니다.

아래 코드에서는 공유기 접속 정보와 Mysql서버 주소를 변경하셔야 합니다. 

[Arduino/Arduino Uno] - Arduino에서 1-wire 온도센서(db18b20)로 온도 측정

[Arduino/Arduino Uno] - arduino UNO에서 DS1302 RTC 모듈 사용하기

[Arduino/Arduino Uno] - arduino에서 esp8266 무선 모듈 테스트

#include <Time.h>
#include <DS1302RTC.h>
#include <OneWire.h>  
#include <DallasTemperature.h>  
#include <string.h>  
 
 
//DS18B20 온도 센서의 데이터선인 가운데 핀을 아두이노 5번에 연결합니다.   
#define ONE_WIRE_BUS 5  
    
//1-wire 디바이스와 통신하기 위한 준비  
OneWire oneWire(ONE_WIRE_BUS);  
    
// oneWire선언한 것을 sensors 선언시 참조함.  
DallasTemperature sensors(&oneWire);  
    
//다바이스 주소를 저장할 배열 선언  
DeviceAddress insideThermometer;
 
 
// Set pins for DS1302 RTC:  CE(reset),IO(dat),CLK
DS1302RTC RTC(2, 3, 4);
 
 
#include <SoftwareSerial.h>  
     
#define SSID "apple"  //공유기 SSID
#define PASS "12345678"   //공유기 비번
#define DST_IP "192.168.0.3"   //MYSQL 서버 주소 
SoftwareSerial dbgSerial(6, 7); // RX, TX 6번,7번핀 
 
 
 
 
void setup()
{
 
  // Setup Serial connection
  Serial.begin(9600);
 
  //ESP8266
  /////////////////////////////////////////////////////////////////////////  
  Serial.setTimeout(5000);  
  dbgSerial.begin(9600);   
  Serial.println("ESP8266 connect");  
  
    
   boolean connected=false;  
   for(int i=0;i<10;i++)  
   {  
       if(connectWiFi())  
       {  
         connected = true;  
         break;  
       }  
   }  
     
   if (!connected){while(1);}  
   delay(5000);  
    
   dbgSerial.println("AT+CIPMUX=0");  
  ///////////////////////////////////////////////////////////////////////////
 
  //ds18b20
  /////////////////////////////////////////////////////////////////////////////////////////////////////////
  //1-wire 버스 초기화  
  sensors.begin();  
      
  //발견한 디바이스 갯수  
  Serial.print("Found ");  
  Serial.print(sensors.getDeviceCount(), DEC);  
  Serial.println(" devices.");  
    
  // parasite power 모드일 때에는  2핀(GND와 DQ 핀)만 연결하면 됨.  
  Serial.print("Parasite power is: ");   
  if (sensors.isParasitePowerMode()) Serial.println("ON");  
  else Serial.println("OFF");  
      
     
  //버스에서 첫번째 장치의 주소를 가져온다.  
  if (!sensors.getAddress(insideThermometer, 0)) Serial.println("Unable to find address for Device 0");   
      
  //버스에서 발견한 첫번째 장치의 주소 출력  
  Serial.print("Device 0 Address: ");  
  printAddress(insideThermometer);  
  Serial.println();  
    
  //데이터시트에서 확인결과 9~12비트까지 설정 가능  
  sensors.setResolution(insideThermometer, 10);  
       
  Serial.print("Device 0 Resolution: ");  
  Serial.print(sensors.getResolution(insideThermometer), DEC);   
  Serial.println();  
  ////////////////////////////////////////////////////////////////////////////////////////////////////////////
  
 
  //DS1302 RTC
  ///////////////////////////////////////////////////////////////////////////////////////////////////
  Serial.println("DS1302RTC Read Test");
  Serial.println("-------------------");
  
  // Activate RTC module
//  digitalWrite(DS1302_GND_PIN, LOW);
//  pinMode(DS1302_GND_PIN, OUTPUT);
 
//  digitalWrite(DS1302_VCC_PIN, HIGH);
//  pinMode(DS1302_VCC_PIN, OUTPUT);
  
  Serial.println("RTC module activated");
  Serial.println();
  delay(500);
  
  if (RTC.haltRTC()) {
    Serial.println("The DS1302 is stopped.  Please run the SetTime");
    Serial.println("example to initialize the time and begin running.");
    Serial.println();
  }
  if (!RTC.writeEN()) {
    Serial.println("The DS1302 is write protected. This normal.");
    Serial.println();
  }
 
 time_t t;
 tmElements_t tm;
 
        
  delay(5000);
 
  
  //시간을 맞춰야할때 주석을 풀어서 설정합니다..
  /*
  tm.Year =  CalendarYrToTm(2016);
  tm.Month = 6;
  tm.Day = 9;
  tm.Hour = 21;
  tm.Minute = 36;
  tm.Second = 00;
  t = makeTime(tm); 

  if(RTC.set(t) == 0) { // Success
    setTime(t);
    Serial.print("RTC set to: ");
    printDateTime(t);
    Serial.println("");
  }
  else
    Serial.println("RTC set failed!");
    */
 //////////////////////////////////////////////////////////////////////////////////////////////
}
 
void loop()
{
  tmElements_t tm;
  char mdate[255],mtime[255];
  
  //현재 날짜 / 시간을 가져옴
  if (! RTC.read(tm)) {
    sprintf( mdate, "%04d-%02d-%02d",
             tmYearToCalendar(tm.Year), tm.Month,  tm.Day);
 
   sprintf(mtime, "%02d:%02d:%02d",
             tm.Hour, tm.Minute, tm.Second );
  } else {
    Serial.println("DS1302 read error!  Please check the circuitry.");
    Serial.println();
    delay(9000);
  }
 
  Serial.print("Requesting temperatures...");  
  sensors.requestTemperaturesByIndex(0); //첫번째 센서의 온도값 읽어옴  
  Serial.println("DONE");  
     
  //센서에서 읽어온 온도를 출력  
  float  tempC = sensors.getTempC(insideThermometer);  
      
  Serial.print("Temp C: ");  
  Serial.println(tempC); 
 
 
  //이하는 데이터베이스에 넣는 부분
 
      String cmd = "AT+CIPSTART=\"TCP\",\"";  
     cmd += DST_IP;  
     cmd += "\",80";  
     Serial.println(cmd);  
     dbgSerial.println(cmd);  
     if(dbgSerial.find("Error"))  
    {  
      Serial.println( "TCP connect error" );  
      return;  
    }  
     
  
    char test[20];  
    String temp(floatToString(test,tempC, 2, 0));  
      
     cmd = "GET /run.php?temp='"+temp+"'&date='"+mdate+"'&time='"+mtime+"'\n\r";  
     dbgSerial.print("AT+CIPSEND=");  
     dbgSerial.println(cmd.length());  
          
       
     Serial.println(cmd);  
       
       
     if(dbgSerial.find(">"))  
     {  
       Serial.print(">");  
       }else  
       {  
         dbgSerial.println("AT+CIPCLOSE");  
         Serial.println("connect timeout");  
         delay(1000);  
         return;  
       }  
       Serial.print(cmd);
       dbgSerial.print(cmd);  
       delay(2000);  
       //Serial.find("+IPD");  
       while (Serial.available())  
       {  
         char c = Serial.read();  
         dbgSerial.write(c);  
         if(c=='\r') dbgSerial.print('\n');  
       }  
       Serial.println("===="); 
 
  
  // Wait one second before repeating :)
  delay (2000);
}
 
    
//디바이스 주소를 출력하는 함수  
void printAddress(DeviceAddress deviceAddress)  
{  
  for (uint8_t i = 0; i < 8; i++)  
  {  
    if (deviceAddress[i] < 16) Serial.print("0");  
        Serial.print(deviceAddress[i], HEX);  
  }  
}  
 
void print2digits(int number) {
  if (number >= 0 && number < 10)
    Serial.write('0');
  Serial.print(number);
}
 
 
//print date and time to Serial
void printDateTime(time_t t)
{
    printDate(t);
    Serial.print(' ');
    printTime(t);
}
 
//print time to Serial
void printTime(time_t t)
{
    printI00(hour(t), ':');
    printI00(minute(t), ':');
    printI00(second(t), ' ');
}
 
//print date to Serial
void printDate(time_t t)
{
    printI00(day(t), 0);
    Serial.print(monthShortStr(month(t)));
    Serial.print(year(t));
}
 
//Print an integer in "00" format (with leading zero),
//followed by a delimiter character to Serial.
//Input value assumed to be between 0 and 99.
void printI00(int val, char delim)
{
    if (val < 10) Serial.print('0');
    Serial.print(val);
    if (delim > 0) Serial.print(delim);
    return;
}
 
 
char * floatToString(char * outstr, double val, byte precision, byte widthp){  
 char temp[16]; //increase this if you need more digits than 15  
 byte i;  
  
 temp[0]='\0';  
 outstr[0]='\0';  
  
 if(val < 0.0){  
   strcpy(outstr,"-\0");  //print "-" sign  
   val *= -1;  
 }  
  
 if( precision == 0) {  
   strcat(outstr, ltoa(round(val),temp,10));  //prints the int part  
 }  
 else {  
   unsigned long frac, mult = 1;  
   byte padding = precision-1;  
     
   while (precision--)  
     mult *= 10;  
  
   val += 0.5/(float)mult;      // compute rounding factor  
     
   strcat(outstr, ltoa(floor(val),temp,10));  //prints the integer part without rounding  
   strcat(outstr, ".\0"); // print the decimal point  
  
   frac = (val - floor(val)) * mult;  
  
   unsigned long frac1 = frac;  
  
   while(frac1 /= 10)   
     padding--;  
  
   while(padding--)   
     strcat(outstr,"0\0");    // print padding zeros  
  
   strcat(outstr,ltoa(frac,temp,10));  // print fraction part  
 }  
  
 // generate width space padding   
 if ((widthp != 0)&&(widthp >= strlen(outstr))){  
   byte J=0;  
   J = widthp - strlen(outstr);  
  
   for (i=0; i< J; i++) {  
     temp[i] = ' ';  
   }  
  
   temp[i++] = '\0';  
   strcat(temp,outstr);  
   strcpy(outstr,temp);  
 }  
  
 return outstr;  
}  
  
boolean connectWiFi()  
{  
   //dbgSerial.println("AT+CWMODE=1");  
     
   String cmd="AT+CWJAP=\"";  
   cmd+=SSID;  
   cmd+="\",\"";  
   cmd+=PASS;  
   cmd+="\"";  
   dbgSerial.println(cmd);  
   Serial.println(cmd);  
   delay(3000);  
    
   if(dbgSerial.find("OK"))  
   {  
     Serial.println("OK, Connected to WiFi.");  
     return true;  
   }  
   else  
   {  
     Serial.println("Can not connect to the WiFi.");  
     return false;  
   }  
 } 

수동으로 넣었을때처럼 데이터가 잘들어갑니다.. 

이제 마지막으로 데이터베이스에 쌓인 데이터를 이용하여 간단한 그래프를 그려볼것입니다.

그래프를 그리기 위해 추가로 설치해야 하는 패키지들입니다.

sudo apt-get install php5-gd  php5-cli

/etc/php5/apache2/conf.d/20-gd.ini 파일을 열어서

앞에  세미콜론이 있으면 아래처럼 ; 제거합니다.

; configuration for php GD module

priority=20

extension=gd.so

아파치 서버를 재시작합니다.

sudo /etc/init.d/apache2 restart

http://www.pchart.net/download 에서 라이브러리를 다운로드 받아서 웹서버의 루트 디렉토리로 옮깁니다.

wget http://www.pchart.net/release/pChart2.1.4.tar.gz

tar xvzf pChart2.1.4.tar.gz

sudo mv pChart2.1.4 /var/www/html/pChart

이제  그래프를 그려줄 php를 작성합니다.

sudo nano /var/www/html/graph.php

db접속 패스워드만 바꾸시면 동작합니다.

<?php
include("pChart/class/pDraw.class.php");
include("pChart/class/pImage.class.php");
include("pChart/class/pData.class.php");
 
 
$db = mysql_connect("127.0.0.1", "root", "패스워드입력");
if ( $db == "" ) { echo " DB Connection error...\r\n"; exit(); }
 
mysql_select_db("testdb",$db);
 
 
 
$Requete = "SELECT * FROM `data` order by time desc limit 30";
$result  = mysql_query($Requete,$db);
while ($row = mysql_fetch_array($result))
{
   $Temperature[] = $row["temperature"];
   $DataTime[] = $row["time"];
}
 
$DataSet = new pData();
$DataSet->addPoints( $Temperature, "Temperature");
$DataSet->addPoints($DataTime,"Timestamp");
 
$DataSet->setAbscissa("Timestamp");
 
$DataSet->setXAxisName("Time");
$DataSet->setAxisName(0,"Temperature");
$DataSet->setAxisUnit(0,"°C");
 
 
 
 
$myPicture = new pImage(1024,600,$DataSet);
$myPicture->setGraphArea(100,60,1000,500);
 
$myPicture->setFontProperties(array("FontName"=>"pChart/fonts/verdana.ttf","FontSize"=>11));
 
 
 $scaleSettings = array("LabelRotation"=>30,
        "XMargin"=>10,"YMargin"=>10,
        "Floating"=>TRUE,"GridR"=>200,"GridG"=>200,"GridB"=>200,
        "DrawSubTicks"=>TRUE,"CycleBackground"=>TRUE );
 $myPicture->drawScale($scaleSettings);
$myPicture->drawSplineChart();
$myPicture->drawLegend(2000,500,array("Style"=>LEGEND_NOBORDER,"Mode"=>LEGEND_HORIZONTAL));
$myPicture->Stroke();
?>
 

실행해본 결과입니다... 날짜는 따로 출력해주면 될듯합니다.

1초마다 Refresh(새로 고침)을 해주도록 소스코드를 고치면 실시간으로 입력되는 데이터를 연속적으로 볼 수있습니다..